Не проходит сообщение LM_CHAR в потомке TWinControl [РЕШЕНО]

[Browny]

Всех приветствую!
Столкнулся с невыполнением обработчика сообщения LM_CHAR в потомке TListBox.

Код: Выделить всё

TPopupListBox = class(TListBox)
private
   FPopup: TComboPopup;
protected
   procedure WMKillFocus(var Message: TLMKillFocus); message LM_KILLFOCUS;
   procedure WMLButtonUp(var Message: TLMLButtonUp); message LM_LBUTTONUP;
   procedure WMChar(var Message: TLMChar); message LM_CHAR;


Обработчики LM_KILLFOCUS и LM_LBUTTONUP отрабатывают нормально.
Проверил сейчас этот код в Delphi 5 - событие работает. Видимо, специфика LCL.
В чём может быть проблема?

[Maxizar]

Хм.. и правда.. но можно попробывать CN_CHAR... или есть какая-то разница??

Код: Выделить всё

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs,
  Messages,LMessages, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormShow(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;
type

  { TPopupListBox }

  TPopupListBox = class(TListBox)
  private
     procedure WMLButtonUp(var Message: TLMLButtonUp); message LM_LBUTTONUP;
     procedure WMChar(var Message: TLMChar); message CN_CHAR;//LM_CHAR;
     procedure WMKillFocus(var Message: TLMKillFocus); message LM_KILLFOCUS;
   //  FPopup: TComboPopup;
  protected

  Public
     constructor Create(TheOwner: TComponent); override;
    destructor Destroy; override;
     end;
var
  Form1: TForm1;
  List:TPopupListBox;
implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormShow(Sender: TObject);
begin
  List:=TPopupListBox.Create(Self);
  List.Left:=10;
  List.Top:=20;
  List.Parent:=Form1;
  List.Visible:=True;
end;

{ TPopupListBox }

procedure TPopupListBox.WMKillFocus(var Message: TLMKillFocus);
begin
  List.Items.Add('Фокус ушел');
  inherited;
end;

procedure TPopupListBox.WMLButtonUp(var Message: TLMLButtonUp);
begin
  List.Items.Add('Отжали');
end;

procedure TPopupListBox.WMChar(var Message: TLMChar);
begin
  List.Items.Add(IntToStr(Message.CharCode));
  inherited;
end;

constructor TPopupListBox.Create(TheOwner: TComponent);
begin
  inherited Create(TheOwner);
end;

destructor TPopupListBox.Destroy;
begin
  inherited Destroy;
end;

end.



[Browny]

Maxizar, ага, работает. Пока в коде так использую, но вопрос всё равно остался. И сейчас озадачился поиском принципиальных отличий сообщений WM_CHAR и CN_CHAR.

[Browny]

Отвечаю сам себе, и на случай, если ещё кому пригодится..
Выдержка кода из $LAZARUS/lcl/interfaces/win32/win32callback.inc

Код: Выделить всё

function WindowProc(Window: HWnd; Msg: UInt; WParam: Windows.WParam; LParam: Windows.LParam): LResult; stdcall;
....
....
begin
  Assert(False, 'Trace:WindowProc - Start');
  FillChar(LMessage, SizeOf(LMessage), 0);
  PLMsg := @LMessage;
  WinProcess := True;
  NotifyUserInput := False;
....
....
  case Msg of
....   
  WM_CHAR:
    begin
      {$ifdef WindowsUnicodeSupport}
      // у меня флаг неактивен
      {$else}
      PLMsg:=@LMChar;
      with LMChar do
      begin
        Msg := CN_CHAR; // а вот и подмена сообщения на пользовательское
        KeyData := LParam;
        CharCode := Word(WParam);
        Result := 0;
        Assert(False,Format('WM_CHAR KeyData= %d CharCode= %d ',[KeyData,CharCode]));
      end;
      WinProcess := false;
      {$endif}
    end;

Собственно, выполнил ещё проверку - подменил оконную функцию, и сделал PostMessage(мойWinControl.Handle, WM_CHAR, 0, 0).
Итог: в саму оконную функцию сообщение попадает. Тестовый проект во вложении к посту..

Если кто найдёт неточности или ошибки в моём сообщении - пожалуйста, напишите и исправьте! Мне это важно и интересно.

[Иван Шихалев]

Может, стоит в исходном сообщении в заголовок добавить «[РЕШЕНО]»?

[Browny]

Спасибо, добавил и немного изменил название темы в более правильную сторону
К слову, считаю, что закрывать тему на добавление записей не надо - вдруг, будут замечания или исправления?